10 PRINT "REGULAR PAYMENT ON A LOAN"
20 PRINT 
29 REM - STATEMENTS 30 TO 100 REQUEST USER INPUT
30 PRINT "TERM IN YEARS";
40 INPUT Y
50 PRINT "PRINCIPAL";
60 INPUT P
70 PRINT "ANNUAL INTEREST RATE";
80 INPUT I
90 PRINT "NUMBER OF PAYMENTS PER YEAR";
100 INPUT N
108 REM - CALCULATE AMOUNT OF REGULAR PAYMENT BY FORMULA;
109 REM - INTEREST CONVERTED FROM PERCENT TO DECIMAL FOR CALCULATIONS
110 R=((I/100)*P/N)/(1-1/((I/100)/N+1)[(N*Y))
119 REM - ROUND OFF TO NEAREST CENT, PRINT
120 PRINT "REGULAR PAYMENT = $"; INT(R*100+.5)/100
129 REM -PRINT BLANK LINE TO SEPARATE DATA FROM QUESTION
130 PRINT
139 REM - RESTART OR END PROGRAM?
140 PRINT "MORE DATA? (1=YES, 0=NO)";
150 INPUT X
160 IF X=1 THEN 20 
170 END
