10 PRINT "PROGRAM FILE 22: NUMERIC AND STRING VARIABLE NAMES"
20 PRINT "        WITH THE SAME INITIAL LETTER."
30 PRINT "    ANSI STANDARD 6.2, 6.4"
40 PRINT
50 PRINT "SECTION 22.1: NUMERIC AND STRING VARIABLE NAMES WITH THE"
60 PRINT "        SAME INITIAL LETTER."
70 PRINT
80 PRINT "THE STANDARD ESTABLISHES A NAME SPACE OF AT LEAST 286 NUMERIC"
90 PRINT "DATA NAMES (A - Z, A0 - Z0, A1 - Z1, ..., A9 - Z9) AND 26"
100 PRINT "DISTINCT STRING DATA NAMES (A$ - Z$)."
102 PRINT
104 PRINT "THIS PROGRAM TESTS THAT DISTINCT VALUES ARE PRESERVED"
106 PRINT "IN VARIABLES WITH SIMILAR, BUT NOT IDENTICAL, NAMES."
110 PRINT
120 PRINT "                              BEGIN TEST."
130 PRINT
140 LET A=10
150 LET A$="ABC"
155 LET A0=A
160 LET A0=100
170 LET A9=109
180 LET B1=123E22
190 LET B0=-123E-22
200 LET B$="18 CHARACTERS LONG"
210 LET B=33
220 IF A<>10 THEN 320
230 IF A$<>"ABC" THEN 320
240 IF A9<>109 THEN 320
250 IF A0<>100 THEN 320
260 IF B<>33 THEN 320
270 IF B$<>"18 CHARACTERS LONG" THEN 320
280 IF B1<>123E22 THEN 320
290 IF B0<>-123E-22 THEN 320
300 PRINT "***  TEST PASSED  ***"
310 GOTO 330
320 PRINT "***  TEST FAILED  ***"
330 PRINT
340 PRINT "                                END TEST."
350 PRINT
360 PRINT "END PROGRAM 22"
370 END
